该指标是一个综合性的技术分析系统，主要包含以下功能：
一、 均线系统
1. 绘制多条均线：
5日均线（白色）
10日均线（青色）
18日均线（红色，变量M18）
30日均线（红色，加粗）
60日均线（绿色）
50日指数均线（绿色）
100日指数均线（灰色，点状线）
181日均线（灰色）
二、 价格通道与支撑阻力
1. 乖离通道：以5日均线为基准，计算其上下特定百分比（120%，115%，110%，90%，85%）的位置，形成通道线，用于观察价格偏离程度。
2. 布林通道中轨：计算50日最高价与最低价的中点，并绘制为粗线。
3. 高低区间：
绘制最近50周期的最高价水平线（紫色）。
绘制最近50周期的最低价水平线（暗黄色）。
绘制上述高低点的中位线（深青色，粗线）。
三、 动态止损
1. 根据公式顶部参数“动态止损度”（默认5）进行计算。
2. 止损价取最近5周期最高收盘价的（100-动态止损度）%。
3. 当最新价跌破止损价时，在图上用粗横线标出止损位，并在其上方显示“止损”文字提示。
四、 特殊K线标识
1. 涨停标识：当涨幅大于等于9%时，将K线绘制为黄色实体。
2. 均线下方的“黑K线”：当“黑”参数为1且收盘价低于20日均线、5日均线也低于20日均线时，将K线绘制为灰色。
3. 涨停但位于20日均线下：当满足涨停条件且收盘价低于20日均线时，将K线绘制为白色实体。
4. 上穿/下穿5日均线标识：
当股价由连续2日低于5日线转为上穿5日线时，用紫红色K线标识，并在最低价位置显示“笑脸”图标。
当股价由连续4日高于5日线转为下穿5日线时，在最高价位置显示“哭脸”图标。
五、 动态行情线
1. 在副图区域绘制两条动态线，分别用深蓝色和深绿色显示最新价。其颜色根据α与β的比较结果（涉及自定义计算）以及最新价相对于高、低区间的位置关系来决定。
六、 技术指标与买卖点提示
1. 集成MACD：计算并显示DIFF、DEA、MACD值。
2. 集成DMI：计算PDI、MDI、ADX、ADXR，并定义DMI金叉条件。
3. 集成CCI：计算CCI指标。
4. 长下影线（针）提示：当出现长下影线形态（下影线长度是实体2倍以上，且最低价创近期新低、低于“离C”通道线），并在“提示”参数开启时，在影线低点标注“针”字。
5. 乖离提示：
当股价上穿“离B”或“离A”通道线（正乖离过大）时，在近期高点标注“超乖离”。
当股价下穿“离C”通道线（负乖离过大）时，在近期低点标注“负乖离”。
6. 三死叉/后金叉提示：
当MACD小于0、10日线上穿5日线、5日均量线下穿10日均量线同时发生时，标注“三死叉”。
当MACD大于0、5日线上穿10日线、5日均量线上穿10日均量线同时发生时，标注“后金叉”。
7. 其他文字提示（需“提示”参数开启或满足特定条件）：
在股价超过5日线7%的位置提示“离!”。
在股价略高于5日线（介于1.005至1倍之间）且未超买时提示“低吸”。
在涨停且前一日大跌（跌幅超5%）时，标注“急挖坑”。
当收盘价低于5日线或5日线低于10日线时，标注“MA5下”和“不持股”。
七、 参数控制
公式顶部设有多个参数（动态止损度、黑、离L、提示、布林M、MMA），用于控制止损幅度、是否显示灰色K线、是否显示文字提示等功能，默认值均为0（关闭）。
动态止损度:=5;
黑:=0;
离L:=0;
提示:=0;
布林M:=0;
MMA:=0;
五:MA(CLOSE,5),COLORWHITE;
十:MA(CLOSE,10),COLOR00FFFF;
M18:=MA(CLOSE,18),COLORRED;
离基:=五;
离O:=离基*1.20,COLOR555555;
离A:离基*1.15,COLOR555555;
离B:离基*1.10,COLOR555555;
离C:离基*0.90,COLOR555555;
离D:=离基*0.85,COLOR333333;
EXP50:=EXPMA(CLOSE,50),COLORGREEN;
MA30:MA(CLOSE,30),LINETHICK1,COLORRED;
MA60:MA(CLOSE,60),COLORGREEN;
β0:=(H-L)/2+L,LINETHICK0;
α:=β0,LINETHICK0;
β:=REF(β0,1),LINETHICK0,COLORGREEN;
γ:=REF(β0,2),LINETHICK0,COLORMAGENTA;
高:PLOYLINE(1,CONST(HHV(H,50))),COLOR770077,LINETHICK1;
低:=PLOYLINE(1,CONST(LLV(L,50))),COLOR777700,LINETHICK1;
中:=PLOYLINE(1,(高-低)/2+低),COLOR005555,LINETHICK4;
止损价:=CONST(HHV(C,5)*(100-动态止损度)/100);
止:PLOYLINE(CONST(C)<=止损价,止损价),COLOR888800,LINETHICK4;
DRAWTEXT(DYNAINFO(7)<=止损价 AND ISLASTBAR,止损价*1.05,'止损');
AA:=CLOSE/REF(C,1)>=1.09;
BA:=CLOSE/REF(C,1)>=1.09;
DRAWKLINE(H,O,L,C);
STICKLINE(AA,O,C,2.5,1),COLORYELLOW;
MA1:=MA(CLOSE,5),COLORRED;
MA2:=MA(CLOSE,10),COLORYELLOW;
MA3:=MA(CLOSE,20),COLOR770077;
E50:=EXPMA(CLOSE,50),LINETHICK1,POINTDOT,COLORLIGREEN;
E100:=EXPMA(CLOSE,100),POINTDOT,COLORGRAY;
MA181:MA(C,181),COLORGRAY;
IF(CONST(α>β) AND DYNAINFO(7)>0,DYNAINFO(7),DRAWNULL),COLOR000088,LINETHICK1;
IF(CONST(α<=β)AND DYNAINFO(7)>0 ,DYNAINFO(7),DRAWNULL),COLOR008800,LINETHICK1;
IF(CONST(α>β) AND DYNAINFO(7)>0 AND DYNAINFO(7)>=高*0.99,DYNAINFO(7),DRAWNULL),COLOR000088,LINETHICK1;
IF(CONST(α<=β)AND DYNAINFO(7)>0 AND DYNAINFO(7)<=低*1.01 ,DYNAINFO(7),DRAWNULL),COLOR008800,LINETHICK1;
N1:=12;
N2:=26;
N3:=9;
DIFF:=(EMA(CLOSE,N1) - EMA(CLOSE,N2));
DEA:=EMA(DIFF,N3);
MACD:=(2 * (DIFF - DEA));
MACD2:=MACD;
SARH:=CLOSE>SAR(4,2,20);
五V:=MA(V,5);
TYP:=(HIGH+LOW+CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
STICKLINE(C<MA3 AND 黑=1,H,L,0,0),COLOR555555;
STICKLINE(MA1<MA3 AND 黑=1,O,C,2.5,1),COLOR555555;
STICKLINE(BA AND C<MA3,O,C,2.7,1),COLORWHITE;
N:=14;
M:=6;
HD :=HIGH-REF(HIGH,1);
LD :=REF(LOW,1)-LOW;
DMP:=EXPMEMA(IF(HD>0&&HD>LD,HD,0),N);
DMM:=EXPMEMA(IF(LD>0&&LD>HD,LD,0),N);
TR1:=EXPMEMA(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),N);
PDI:=DMP*100/TR1;
MDI:=DMM*100/TR1;
ADX:=EXPMEMA(ABS(MDI-PDI)/(MDI+PDI)*100,M);
ADXR:=EXPMEMA(ADX,M);
DMIJX:=CROSS(PDI,MDI) AND C>O ;
头上边:=MAX(O,C),NODRAW;
头下边:=MIN(O,C),NODRAW;
垂头:=ABS(O-C),NODRAW;
长针:=(头下边-L),NODRAW;
垂:=长针/垂头>2 AND (H-头上边)<=长针 AND L<REF(L,1) AND O<REF(C,1),NODRAW;
DRAWTEXT(垂 AND L<=LLV(L,3) AND L<离C AND 提示,L/1.01,'针') AND 提示,COLORGREEN,LINETHICK4;
DRAWTEXT(H>MA(CLOSE,5)*1.07 AND ISLASTBAR AND 提示,H*1.01,'离!'),COLORGREEN,LINETHICK2;
DRAWTEXT(L<MA(CLOSE,5)*1.005 AND L>MA(CLOSE,5) AND 提示=0 AND H<MA(CLOSE,5)*1.07 AND ISLASTBAR,L/1.02,'低吸'),COLORGREEN,LINETHICK2;
上5日:=REF(EVERY(C<MA1,2),1) AND CROSS(C,MA1);
STICKLINE(上5日,H,L,0,0),COLORFF00FF;
STICKLINE(上5日,O,C,2.7,0),COLORFF00FF;
DRAWICON(上5日,L,1);
破5日:=REF(EVERY(C>MA1,4),1) AND CROSS(MA1,C);
DRAWICON(破5日,H,2);
DT:=REF(CLOSE/REF(C,1),1)<=0.95;
DRAWTEXT(AA AND DT AND CURRBARSCOUNT<60 ,H,'急挖坑'),COLORGREEN;
SC1:=MACD.MACD<0;
SC2:=CROSS(十,五);
SC3:=MA(V,5)<MA(V,10);
SC:=SC1 AND SC2 AND SC3 ;
DRAWTEXT(SC AND CURRBARSCOUNT<10 ,HHV(H,5),'三死叉'),COLORWHITE;
JC1:=MACD.MACD>0;
JC2:=CROSS(五,十);
JC3:=MA(V,5)>MA(V,10);
JC:=JC1 AND JC2 AND JC3 ;
DRAWTEXT(JC AND CURRBARSCOUNT<20 ,LLV(L,5),'后金叉'),COLORYELLOW;
DRAWTEXT(CROSS(H,离B) AND CURRBARSCOUNT<10 ,HHV(H,3),'超乖离'),COLORYELLOW;
DRAWTEXT(CROSS(H,离A) AND CURRBARSCOUNT<10 ,HHV(H,3),'超乖离'),COLORYELLOW;
DRAWTEXT(CROSS(离C,L) AND CURRBARSCOUNT<10 ,LLV(L,3),'负乖离'),COLORWHITE;
DRAWTEXT((C<MA(C,5) OR MA(C,5)<MA(C,10)) AND CURRBARSCOUNT<2,HHV(H,5)*1.04,'MA5下'),COLORRED;
DRAWTEXT((C<MA(C,5) OR MA(C,5)<MA(C,10)) AND CURRBARSCOUNT<2 ,HHV(H,5)*1.01,'不持股'),COLORRED;
