通达信『极简顶底』辨顶底，简简单单潜伏底部 精准捕捉潜伏牛股
公式介绍
极简顶底包含主图、副图、三套公式，核心围绕趋势判断与低位牛股潜伏设计。主图以13日均线划分趋势（红色向上、绿色向下），结合买卖线交叉标注B（买）、S（卖）信号，搭配参考价辅助判断价格位置；副图融合KDJ改良指标与MACD背离逻辑，筛选低位满足多重条件的个股并标注“★潜伏”信号；公式在副图基础上，叠加均线多头、剔除ST/科创板/北交所等风险标的，精准锁定符合条件的潜伏牛股。
使用方法
1. 主图：红色K线且13日均线向上为上升趋势，B信号出现可关注买入；绿色K线且均线向下为下跌趋势，S信号出现需警惕卖出。
2. 副图：当出现黄色“★潜伏”标识时，代表个股处于低位且具备上涨动能，可重点跟踪。
3. ：直接调用公式，一键筛选出符合“低位+趋势转好+无风险标签+股价超3元”的潜伏牛股，结合主图趋势确认后，可作为买入参考。
整套公式极简易懂，无需复杂分析，新手也能快速上手，适合波段操作与低位布局。
总结
1. 主图看趋势：13日均线颜色+BS信号判断买卖时机；
2. 副图找标的：“★潜伏”标识提示低位潜力股；
3. 做筛选：自动过滤风险标的，精准锁定符合条件的牛股。
极简顶底主图源码：
{ 极简顶底主图源码如下: }
N:=5;
趋势线:MA(CLOSE,13),COLORBLACK;
IF(MA(CLOSE,13)< REF(MA(CLOSE,13),1),MA(CLOSE,13),DRAWNULL),COLORGREEN,LINETHICK2;
IF(MA(CLOSE,13)>=REF(MA(CLOSE,13),1),MA(CLOSE,13),DRAWNULL),COLORRED,LINETHICK2;
买线:=EMA(C,2);
卖线:=EMA(SLOPE(C,26)*15+C,45);
BU:=CROSS(买线,卖线);
SEL:=CROSS(卖线,买线);
DRAWBMP(BU,L*0.999,'B');
DRAWBMP(SEL,H*1.02,'S');
STICKLINE(买线>=卖线,LOW,HIGH,0,1),COLORLIRED;
STICKLINE(买线>=卖线,CLOSE,OPEN,8/3,1),COLORLIRED;
JC:=(REF(C,3)+REF(C,5)+REF(C,7)+REF(C,8)+REF(C,13)+REF(C,21))/6;
参考价:=SMA(JC,5,1),COLORCYAN;
价:=IF(C>=参考价,参考价,参考价*0.98 ), CIRCLEDOT,COLOR0000FF;
STICKLINE(买线< 卖线,LOW,HIGH,0,1),COLORCYAN;
STICKLINE(买线< 卖线,CLOSE,OPEN,8/3,1),COLORCYAN;
{ 极简顶底副图源码如下: }
最低:=LLV(LOW,50);
最高:=HHV(HIGH,50);
ZBSC:=EMA((CLOSE-最低)/(最高-最低)*100,3);
K:=EMA(ZBSC,8);
D:=MA(K,8);
DIF:=EMA(CLOSE,20)-EMA(CLOSE,120);
DEA:=EMA(DIF,13);
量柱:=(DIF-DEA)*2;
ABC1:=量柱>0 AND CROSS(DIF,DEA) AND DIF< 0;
KD:=CROSS(K,D) AND K<=20;
ABC2:=EXIST(KD,15) AND K<=50;
ABC3:=K>D;
潜伏牛股:=FILTER(ABC1 AND ABC2 AND ABC3,15);
DRAWTEXT(潜伏牛股,40,' ★潜伏'),COLORYELLOW;
STICKLINE(潜伏牛股,50,38,1,0),COLORYELLOW ;
STICKLINE(潜伏牛股,38,12,2,0),COLORRED;
STICKLINE(潜伏牛股,12,0,3,0),COLORFFFFFF;
{ 极简顶底选股源码如下: }
最低:=LLV(LOW,50);
最高:=HHV(HIGH,50);
ZBSC:=EMA((CLOSE-最低)/(最高-最低)*100,3);
K:=EMA(ZBSC,8);
D:=MA(K,8);
DIF:=EMA(CLOSE,20)-EMA(CLOSE,120);
DEA:=EMA(DIF,13);
量柱:=(DIF-DEA)*2;
ABC1:=量柱>0 AND CROSS(DIF,DEA) AND DIF< 0;
KD:=CROSS(K,D) AND K<=20;
ABC2:=EXIST(KD,15) AND K<=50;
ABC3:=K>D;
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
DTP:=MA5>MA10 AND MA10>MA20;
QXS:=NOT(CODELIKE('4'));
QKC:=NOT(CODELIKE('688'));
QST:=IF(NAMELIKE('S'),0,1);
QXX:=IF(NAMELIKE('*'),0,1);
QBJ:=NOT(CODELIKE('8'));
ABC4:=QXS AND QST AND QKC AND QXX AND QBJ;
潜伏牛股:FILTER(ABC1 AND ABC2 AND ABC3 AND ABC4 AND C>3 ,15);
